macros

Las macros son un método mediante el cual podemos definir una serie de acciones para que se ejecuten de forma consecutiva con una única pulsación de un botón del teclado o ratón. Esto permite automatizar en cierto grado acciones repetitivas o que se suelen ejecutar con frecuencia. El uso de macros no es ilegal siempre y cuando se utilicen desde dentro el juego.

Limitaciones

Cada comando debe ir en una nueva linea.
Dentro de las macros sólo se podrán utilizar las acciones que proporcionan comandos del juego además de los que incorporan los AddOns o Complementos. Esto abarca los comandos específicos para macros además de los estándar y los emotes.
Las macros pueden contener un máximo de 255 caracteres.
Los nombres de habilidades y objetos deberán escribirse en el idioma activo del juego, tal y como figura en la descripción que se muestran en el juego.
No se pueden lanzar dos hechizos en la misma macro si el tiempo de reutilización o el Cooldown de uno afecta al siguiente hechizo (incluyendo el Cooldown Global). Sólo en algunos casos funciona con hechizos instantáneos intercalando el comando /stopcasting entre cada hechizo.
No existen comandos de pausa o retardo.

Primeros pasos

1. Abrir ventana de edición de macros pulsando el botón macros del menú principal (tecla Esc), o directamente se escribe desde el chat el comando ‘/macro’.

2. En el editor de macros se pulsa el botón ‘Nuevo’ para crear una nueva macro; seleccionar un icono y un nombre y pulsar ‘Aceptar’.

3. En el cuadro de texto se escribe la secuencia de comandos, uno por linea.

4. Una vez completada la macro arrastramos su icono correspondiente a un hueco de una de las barras de acciones.

5. Para ejecutar la macro pulsamos en el botón de acción o la tecla asignada al mismo.

¿Qué se puede hacer con una macro? ¿Y qué no se puede?

Las macros permiten hacer aquellas acciones que requieran la presencia de una habilidad, frase, emociones o incluso equipar o desequipar objetos.

Lo que nunca hará una macroes jugar por ti. Eso incluye la elección de hechizos automáticamente, ni caminar, ni recoger objetos de los cadáveres. En definitivamente no hará nada que requiera tu intervención directa. Si encuentras un programa o addon que haga esto por ti, es ilegal y te banearían la cuenta. Siendo más específicos, esta es la lista de cosas que no puedes hacer con macros:

1- Una macro NO PUEDE COMPROBAR SI UN HECHIZO ES USABLE.
2- Una macro no podrá comprobar si un hechizo está en tiempo de reutilización
3- Cualquier condición que se te ocurra que te ahorraría esfuerzo de elección de botones, entonces no se puede hacer (por ejemplo comprobar la vida que le queda a un jefe, comprobar el maná que tenga, qué hechizo está lanzando, su especialización de talentos, etc etc).
4- Jamás podrás hacer que una macro lance dos hechizos simultáneamente salvo que éstos se anulen entre sí (que son muy pocos hechizos) o que no compartan tiempo de reutilización global (por ejemplo sí puedes hacer una macro con "Enfoque interno" y "Sanación relámpago" pero nunca con "Punición" y "Fuego sagrado" teniendo en cuenta que ambas condiciones de ejecución de ambos hechizos son correctas a la vez).

¿Dónde se guardan las macros?

Un dato interesabte a saber es que las macros las guarda el servidor y además se genera una copia en tu propio ordenador. Así si entras al WoW desde varios ordenadores, siempre tendrás a tu disposición tus macros preferidas.

Tipos y Estructura de macros:

Las macros tienen una estructura estándar que podrás seguir prácticamente siempre. Veamos un ejemplo para una macro con dos hechizos y condiciones distintas para cada hechizo:

/acción [condición1, condición2] habilidad; [condiciones] habilidad;

Además las macros se pueden dividir en 4 tipos. Las macros de texto (como la que viste en el punto 5), las macros de habilidades (que son las más usuales y dónde haremos más incapié), las macros hechas con código LUA (que son aquellas macros hechas con código de Addons, que no explicaré en esta guía por su complejidad) y las macros relacionadas con el equipo.

Macros tipo texto:

Las macros tipo texto son aquellas que tienen como finalidad anunciar algo por algún canal. La estructura es:

/acción /canal texto

Macros de habilidades:

Estas macros son aquellas que necesitan un comando que le diga qué hacer y bajo qué condiciones. Cada comando, además, puede tener ciertas estructuras que se explicarán cuando sea necesario. Pero la base a segir es:

/acción [condiciones] habilidad;

Macros de equipo:

Hay ciertas macros que nos permiten equiparnos objetos o usarlos. La estructura de las mismas es muy peculiar, así que las obviaremos en este punto y se explicará más adelante.

MACROS TIPO TEXTO:

- ACCIÓN:

.- %t:

        El comando " %t " no es en sí un comando, sino una opción que cabe destacar para las macros de cat (o incluso para el chat en sí mismo). Al poner %t el juego escribirá el nombre de tu objetivo. en caso de no tener objetivo pondrá "sin objetivo".

/p ¡Mi objetivo se llama %t!

- %f:

        El comando "%f" funciona igual que el "%t" pero en vez del nombre del objetivo dirá el nombre de tu focus.

/p ¡Mi focus se llama %f!

CANALES:

Utilización:

A la hora de poer un canal se pondrá delante del texto. En el ejemplo siguiente donde pone CANAL es lo que deberás sustituir por el apartado siguiente:

/CANAL ¡Hola, esto es un texto!

Lista de canales:

- s: Decir

- g: Clan

- p: Grupo

- ra: Banda

- rw: Aviso de Banda

- bg: Campo de batalla

MACROS DE HABILIDADES:

ACCIONES:

ACCIONES DE COMBATE:

- CAST:

Esta es la macro principal, la que más usarás (se puede cambiar "cast" por "lanzar" si juegas en castellano. Pero yo no lo recomiendo puesto que cast seguro que no falla y además ocupa menos caracteres). Básicamente sigue la siguiente estructura:

/cast [condiciones] Habilidad;

- CASTSEQUENCE:

En esencia funciona igual que el CAST pero tiene otra finalidad. Su función no es la de lanzar un hechizo, sino la de concatenar varios hechizos bajo las mismas condiciones. La diferencia es que la estructura es relativamente diferente y usa unas condiciones diferentes.

/castsequence reset=condiciones Habilidad1, Habilidad2, Habilidad3;

Después del reset, donde pone condiciones, podemos añadir lo siguiente: un número (que equivaldría a segundos), target (cambio de objetivo), combat (cuando salgas o entres en combate), shift, alt, ctrl (cuando pulses cualquiera de estas teclas). Puedes poner todos los condcionantes que quieras separados con una /. Cuandose cumpla algunad e las condiciones la macro volverá a su punto de partida. Por supuesto también volverá a su punto de partida cuando llegue a la última habilidad.

ACCIONES SUELTAS:

- STOPCASTING:

Este comando corta cualquier hechizo que estés lanzando:

/stopcast [condiciones]

- CLEARTARGET:

Permite limpiar el objetivo que tengamos:

/cleartarget [condiciones]

- FOCUS:

Permite crear un objetivo "focus":

/focus [condiciones]

- CLEARFOCUS:

Permite limpiar nuestro objetivo "focus":

/clearfocus [condiciones]

- STOPMACRO:

Permite detener una macro:

/stopmacro [condiciones]

- CANCELAURA:

Permite quitarse un beneficio:

/cancelaura [condiciones] beneficio;

- CANCELFORM:

Permite quitarse una forma. Las "formas" son aquellas habilidades que te habilitan una barra alternativa (como la "Forma de las sombras" del sacerdote). La excepción a este tipo de formas son los guerreros ya que tienen que estar en una forma obligatoriamente.

/cancelform [condiciones]

- STARTATTACK:

Permite empezar a atacar. La diferencia con "atacar" de tu libro de hechizos es que ese "atacar" ataca si no estás atacando y si estás atacando deja de atacar. Con este comando atacas sí o sí:

/startattack [condiciones]

- STOPATTACK:

Mismo caso que el anterior, pero obliga a parar de atacar:

/stopattack [condiciones]

- PETAGGRESSIVE:

Pone a tu mascota en agresivo:
/petaggressive [condiciones]

- PETATTACK:

Envía a tu mascota a atacar:
/petattack [condiciones]

- PETDEFENSIVE:

Pone a tu mascota en defensivo:
/petdefensive [condiciones]

- PETFOLLOW:

Pone a tu mascota en seguirte, contrario a "Petstay":
/petfollow [condiciones]

- PETPASSIVE:

Pone a tu mascota en pasivo:
/petpassive [condiciones]

- PETSTAY:

Deja quieta a tu mascota en el sitio, contrario a "Petfollow":
/petstay [condiciones]

ACCIONES GENERALES:

- #SHOW:

Muestra el icono de la primera habilidad de la macro. Puedes añadirle después del "show" el nombre de un hechizo, el nombre de un objeto, la "Bagid Slot" o la "InvSlot". En cualquiera de los casos mostrará el icono que haya en esos lugares.
Nota: si bien se puede poner un objeto por su posición en las bolsas o su lugar en una mochila, es realmente tedioso dar con el que corresponde y además es poco práctico ya que al acceder al banco cambia todos esos números cambiando también el icono correspondiente.
#show [condiciones] Habilidad/objeto

- #SHOWCOOLDOWN:

Es igual que el "Show" pero además muestra el tiempo de reutilización de la primera habilidad después del "Showcooldown" o bien de la primera habilidad de la macro en caso de no tener nada el "showcooldown":
#showcooldown [condiciones] Habilidad/objeto

- #SHOWTOOLTIP:

Es igual que el "Showcooldown" pero además muestra la descripción de la habilidad que muestre el "showtooltip".
NOTA: Para que te muestren los iconos debes escoger como icono el "?" rojo.
#showtooltip [condiciones] Habilidad/objeto

- La ! en los hechizos:

Muchos hechizos del wow funcionan de distinta manera al pulsarlos una vez o la siguiente. Por ejemplo las auras de paladín que la primera que pulses se activará y la siguiente se desactivará. Con esta acción podemos hacer que un hechizo siempre trate de activarse, en vez de activarse y desactivarse en cada pulsación:

/cast !Aura de reprensión

CONDICIONES:

Cuando hablamos de una condición nos referimos a un hecho que una macro puede comprobar y actuar en consecuencia. Éstas sirven para dar a una misma macro distintos usos dependiendo de dichas condiciones. Por poner un ejemplo de la vida real una condición sería si la luz está encendida o no. Si no lo está nos levantaríamos a encenderla. Y en caso de estar encendida seguramente el siguiente paso nos sentaríamos. Explicado en lenguaje de macros de wow sería algo así:

/cast [luzapagada] Ecender Luz; Sentarse;

Así pues en esta sección se explicarán esas condiciones que podemos usar para que un comando actúe de una manera o de otra. Ten en cuenta que la mayoría de las opciones admiten un "no" delante para comprobar lo contrario. Por ejemplo:

/cast [combat] Esfumarse; Sigilo;

Esto haría que si estás en combate usarías Esfumarse y en cualquier otro caso usarías Sigilo.

/cast [nocombat] Sigilo; Esfumarse;

Esto haría que si no estás en combate usarías Sigilo y en cualquier otro caso harías Esfumarse.

Como puedes ver el resultado de este ejemplo es el mismo al final, pero puede que en ciertas circustancias quieras hacer cosas distintas y tengas que comprobar cosas distintas. ¡Todo depende de tu imaginación!

Condiciones de objetivo

Puedes poner estas condiciones en los mismos corchetes pero no tendría ninguna lógica ya que son antónimas entre sí:

[ul]- HARM:
Comprueba si tu objetivo actual es enemigo.
/cast [harm] Punición; Sanación relámpago;
- HELP:
Comprueba si tu objetivo actual es amigo.
/cast [help] Sanación relámpago; Punición;

Condiciones de botón

Estas condiciones pueden ponerse dentro de los mismos corchetes.

- BUTTON:

Comprueba si se activa la macro con algún botón en concreto del ratón: 1 es Click derecho, 2 click izquierdo, 3 Click central y a partir de ahí tantos como botones tenga tu ratón. Tendrás que probar a cual corresponde cual. Ten en cuenta que puedes cambiar BUTTON por BTN.
/cast [btn:2] Sanación Superior; Sanación relámpago;

- MODIFIER:

Comprueba si mientras se activa la macro estamos pulsando alguna de las siguientes teclas: Alt, Ctrl o Shift. Ten en cuenta que puedes cambiar MODIFIER por MOD.
/cast [mod:ctrl] Sanación Superior; Sanación relámpago

Condiciones de estado

Estas condiciones pueden ponerse dentro de los mismos corchetes.

- COMBAT:

Comprueba si estás con combate.

/cast [combat] Esfumarse; Sigilo;

- DEAD:

Comprueba si el objetivo está muerto.

/cast [dead] Canibalismo; Punición;

- EXISTS:

Comprueba si el objetivo existe. (No se me ocurre ningún ejemplo simple realista, así que dejo lo básico)

/cast [exists] Sanación Relámpago;

- STEALTH:

Comprueba si estás en sigilo

/cast [stealth] Emboscada; Puñalada;

- STANCE o FORM:

Comprueba la estancia en la que estás. Por estancia hablamos aquellos estados que activan barras distintas al usarla (como las transformaciones de druida o las actitudes de guerrero. Las excepciones son el Angel del Sacerdote, lobo del chamán y la forma de demonio del brujo: http://img52.imageshack.us/img52/5909/estances.png.

/cast [Stance:1] Abrumar; [Stance:3] Torbellino; Golpe heroico;

/cast [stance:1/3] Golpe heroico; [stance:2] Provocar;

Condiciones de a qué objetivo comprobar

Estas condiciones son algo extrañas. Realmente no comprueban nada, simplemente es la aclaración de a quién va dirigido el hechizo resultante de la macro.

- @TARGET:

El hechizo va dirigido a tu objetivo.

/cast [@target] Sanación relámpago;

- @TARGETTARGET:

El hechizo va dirigido al objetivo de tu objetivo.

/cast [@targettarget] Sanación relámpago;

- @FOCUS:

El hechizo va dirigido a tu focus.

/cast [@focus] Sanación relámpago;

- @FOCUSTARGET:

El hechizo va dirigido al objetivo de tu focus.

/cast [@focustarget] Sanación relámpago;

- @PLAYER:

El hechizo va digirido a ti mismo.

/cast [@player] Sanación relámpago;

- @MOUSEOVER:

El hechizo va dirigido al personaje que esté debajo de tu puntero que no seas tu. Sirve con las interfaces de banda tanto del propio wow como el grid o similares. También sirve, por supuesto, a los personajes en pantalla directamente.

/cast [@mouseover] Sanación relámpago;

- @MOUSEOVERTARGET:

El hechizo va dirigido al objetivo del personaje que esté debajo de tu puntero.

/cast [@mouseovertarget] Sanación relámpago;

- @NOMBRE:

El hechizo irá dirigido al jugador o enemigo que pongas en NOMBRE. Dicho objetivo debe estar en tu grupo o banda.

/cast [@Menganito] Secretos del oficio;

8.2.5.- Condiciones de terreno

- FLYABLE:

Comprueba si el mapa donde estás puedes volar:

/cast [flyable] Grifo dorado; Corcel blanco presto;

- FLYING:

Comprueba si estás volando:

/cast [flying] Levitar; Grifo dorado;

- INDOORS:

Comprueba si estás en interiores:

/cast [indoors] Sprint; Corcel blanco presto;

- OUTDOORS:

Comprueba si estás en exteriores:

/cast [outdoors] Corcel blanco presto; Sprint;

- MOUNTED:

Comprueba si estás montado. No se me ocurre ningún ejemplo simple que sea útil, así que pongo un ejemplo sin utilidad real:

/cast [mounted] Sigilo; Esfumarse

- SWIMMING:

Comprueba si estás nadando:

/cast [swimming] forma acuática;

Condiciones de hechizo

- CHANNELING:

Comprueba si estás canalizando un hechizo. No se me ocurre ningún ejemplo tal cual, pero sí con "nochanneling"):

/cast [nochanneling:Tortura mental] Tortura mental;

MACROS DE EQUIPO:

ACCIONES:

USE:

Los "/use" tienen 3 usos. El más común es ponerle al lado el nombre de un objeto:
/use [condiciones] Nombredelobjeto;
Otro uso es ponerle que use una casilla en concreto de tus bolsas (siendo las bolsas del 0 al 4 y del 1 hasta la última casilla empezando siempre por la izquierda arriba):
/use [condiciones] numerobolsa numerohueco
Y finalmente el de usar el objeto equipado dependiendo de la casilla:
/use [condiciones] casilla
Este apartado realmente es el más interesante puesto que nos permite, entre otras cosas, automatizar los usos de nuestro equipo siempre que estén disponibles. Ten en cuenta que esta lista es para usar los posibles "usos" que tengan cada uno de estos objetos:
1-Cabeza
2- Colgante
3- Hombreras
4- Camisa
5- Pecho
6- Cinturón
7- Pantalones
8- Botas
9- brazaletes
10- Guantes
11- Primer anillo
12- Segundo anillo
13- Primer abalorio
14- Segundo abalorio
15- Capa
16- Arma en la mano principal
17- Agarre de la mano izquierda
18- Arma a distancia
19- Tabardo
20- Primera bolsa
21- Segunda bolsa
24- Tercera bolsa
25- Cuarta bolsa

EQUIP:

Te permite equipar un objeto a través de su nombre:
/equip [condiciones] nombredelobjeto;

EQUiPSLOT:

Te permite equipar un objeto en una casilla de manera específica. Ideal para cuando quieres cambiar un anillo en concreto o armas de 1 mano. La lista de "Casillas" es la misma que en el apartado anterior;
/equipslot [condiciones] Casilla nombredelobjeto;

9.1.4.- EQUiPSET:

Te permite equiparte un set que hayas guardado usando el gestor de equipamiento de Blizzard:
/equipset] [condiciones] nombredelset;

10.- AGRADECIMIENTOS

- A Wowwiki y google por ayudarme a buscar información al respecto cuando tenía dudas.
- A Aliisza y Habibals por las ayudas esporádicas dadas.
- A Oxy por comentar el dato que faltaba.
- A Søyer por informarme del comando %f
- A Ysondra por pasar la guía a PDF con un formato genial!


Guía Avanzada

NOTA: Los comandos están en inglés aunque muchos tienen su equivalente en español, pero en inglés suelen ser más cortos y por el límite de 255 caracteres, es mejor usar éstos. Equivalencia de comandos: http://forums.wow-europe.com/thread.html?topicId=281688483&sid=4.

Cambios en 2.0
En el parche 2.0, coincidiendo con la salida de la expansión La Cruzada Ardiente (Abrv. TBC), se presenta un nuevo sistema de macros con nuevas restricciones pero también posibilidades. En primer lugar: En las macros de TBC no se podrán seleccionar unidades o lanzar hechizos con el interfaz de /script cuando se inicien. Esto quiere decir que la siguiente macro:

/script if (UnitMana(“player”)>54) then CastSpellByName(“Golpe Heroico”); end

….ya no funcionará. La función CastSpellByName() no podrá ser llamada en combate, yTargetUnit(), TargetByName() y funciones similares no serán accesibles ni dentro ni fuera de combate. Otras tantas funciones se han deshabilitado para cuando los personajes estén en combate. No las recuerdo todas de memoria, pero algunas de ellas son las de mascotas: PetAttack() PetF`ollow() PetPassiveMode() PetAggresiveMode() SpellStopCasting(), cambiar de barra de acciones, no será posible programáticamente sin una previa interacción del usuario y a través de las denominadas Plantillas seguras. Estos serán reemplazados con comandos (/slash) que podrán ser usados.

Sintáxis

/comando [opción] acción; [opción1, opción2] acción

El nuevo formato del comando ‘/cast’ (/lanzar) es:

/lanzar [<primer conjunto de opciones>] <primer hechizo>; [<segundo conjunto de opciones>] <segundo hechizo> ; [<tercer conjunto de opciones>] <tercer hechizo>; …

Trucos que se pueden usar con las opciones: Puedes añadir un ‘no’ al comienzo de cada opción (excepto target) para invertirla, ej. con ‘nocombat’ solo se ejecutará si no se está en combate. Separar las opciones con coma ‘,’ funcionará como una sentencia ‘Y’; si ambas opciones son ciertas, se ejecuta. Separar opciones con la barra ‘/’ funcionará a modo de sentencia ‘Ó’ -si cualquiera de las dos se cumple, se ejecuta-. Seleccionando el icono de interrogación ‘?’ en el Editor de Macro, forzará a que la macro presente el icono de hechizo actual de la opción de ‘feedback’.(es decir, muestra el mismo icono del hechizo indicando además el estado de enfriamiento o cooldown).

Pueden indicarse varias cláusulas de condiciones para una acción simple, que será ejecutada si cualquiera de las cláusulas es verdadera. Ej.

/cast [target=target,help,nodead][target=player] Sanación relámpago

…(sería como si cada bloque de corchetes estuviera separado por un ‘Ó’ lógico).

Macro Feedback

El feedback significa que se mostrará el estado de cierta habilidad u objeto en el icono de la macro (enfriamiento, si se puede usar o no, etc).
# y -son prefijos de comentarios en las macros.
Una macro que comience con # show <item o hechizo> usará el feedback para ese hechizo, # show none no mostrará feedback.
De otra manera el primer comando /cast, /randomcast, /castsequence, /use, o /randomuse (/lanzar) será usado para el feedback.
Las secuencias realmente ciclan el item/hechizo mostrado en el feedback para que corresponda con el siguiente paso de la secuencia.
#show y #showtooltip ahora pueden recibir condiciones para actualizarse dinámicamente (ver Opciones más abajo)
A #show y #showtooltip puede facilitarse un número de ranura para que muestre el estado de esa ranura. También se les pueden aplicar condiciones en el mismo formato que /lanzar.

Lanzamiento de Hechizos(casting)

Cuando se lanza una mejora que tiene un rango demasiado alto para un objetivo amigable, el juego automáticamente aplicará el mayor rango posible para el objetivo.
Las habilidades alternables tendrán un retraso de 1.5 segundos tras ser lanzadas antes de que puedan ser canceladas haciando click sobre ellas, para prevenir que puedan cancelarse por error. En cualquier caso todavía se puede hacer click derecho para cancelarse.

Lógica
La manera en que ahora funcionan las macros es la siguiente: La primera opción se evalúa. Si es cierta, entonces el primer hechizo se lanza. Si son falsas, el siguiente conjunto de opciones se comprueba, y si se cumplen, se lanza el siguiente hechizo, y así sucesivamente. Sin embargo ten encuenta que sólo un hechizo se puede lanzar simultáneamente. Tan pronto como un conjunto de opciones sea considerada verdadera, el juego lanza el hechizo correspondiente y esa línea de la macro ya está hecha.

El primer hechizo en una macro que falle prevendrá de futuros lanzamientos en la macro como si el enfriamiento (cooldown) global de 1.5 seg hubiera saltado. A los comandos /cast, /use, /cancelaura, /changeactionbar, /equip, /target, /focus, /assist, /targetenemy, /targetfriend, /targetparty, y /targetraid se les pueden asignar múltiples acciones y condiciones sobre las que usar esas acciones. La primera acción coincidente será usada. (Esto se entiende mejor en los ejemplos).

Los nombres de items pueden usarse intercaladas con nombres hechizos en /cast, /castrandom, y /castsequence. Venenos, alimentar a la mascota, etc., será incluso más fácil en las macros: /cast Feed Pet (/lanzar Alimentar Mascota) y luego /use Costillas de cerdo secas. También se podrá hacer click en la comida en la barra de acciones cuando tengas seleccionado Alimentar a la mascota u otros objetos de hechizo con selección.

Comandos
(NOTA: los caracteres < > se utilizan para delimitar los parámetros, pero no deben escribirse)

Comandos de acción
/cancel – Cancela la acción en curso
/cancelaura – Cancela el aura activa
/focus – Establece el objetico como foco (ver más abajo)
/stopmacro – Detiene la ejecución de la macro
/cancelform – Cancela la forma actual (druida, sacerdote sombras, etc)

Barra de acciones
/changeactionbar <num> – Cambia de barra de acción
/swapactionbar <num1> <num2> – Intercambia dos barras de acción

Atacar
/startattack [unidad] – Comienza a atacar a la unidad (target, focus, targettarget, focustarget, etc)
/stopattack – Detiene el ataque

Ventajas(buffs)/Auras
/cancelaura <nombre> – Cancela un aura como si se hubiera pulsado el botón derecho sobre ella
/cancelform – Cancela cualquier forma (formas druida, forma de sombra sacerdote, etc)

Botones
/click NombreBoton [botónratón]

Hechizos/habilidades
/cast <hechizo> – Lanza/usa un hechizo/habilidad
/castrandom <hechizo1>,<hechizo2>,<hechizo3> – intentará lanzar un de los hechizos indicados de manera aleatoria
/castsequence – Lanza una secuencia de hechizos (explicado más abajo)
/stopcasting – intentará cancelar el hechizo que se está lanzando actualmente

Objetos y Equipo
/equip <nombreObj> – Equipa un objeto
/equip <item:id> – Equipa un objeto con id /equip item:25640
/equipslot <ranura> <nombreObj> – Equipa un objeto en una ranura dada
/use <nombreObj> – Usa un objeto por su nombre
/use <ranura> – Usa el objeto que haya en una ranura
/use <idbolsa> <ranurabolsa> – Usa un objeto que haya la ranura de una bolsa
/userandom <item1>, <item2>, <item3> – Intentará usar aleatoriamente uno de los objetos indicados

Control de Mascota
/petaggressive – Pone la mascota en modo agresivo
/petattack – Ordena atacar a la mascota
/petautocaston <spell> – Activa el modo auto de una habilidad de mascota
/petautocastoff <spell> – Desactiva el modo auto de una habilidad de mascota
/petdefensive – Pone la mascota en modo defensivo
/petfo´llow (el ´ es para evitar el filtro de tacos) – Pone la mascota en modo seguimiento
/petpassive – Pone la mascota en modo pasivo
/petstay – Ordena a la mascota quedarse quieta
/petautocasttoggle <habilidad> – Alterna el modo automático de la habilidad de la mascota

Selección Objetivo
/assist – Asiste al objetivo actual
/clearfocus – Elimina el foco actual
/cleartarget – Deselecciona el objetivo actual
/target <nombre> – Selecciona a un objetivo con un nombre similar
/targetexact <nombre> – Selecciona a un objetivo cuyo nombre coincida exactamente con el indicado

Ciclo de Objetivo
/targetenemy – Selecciona el enemigo más cercano
/targetlastenemy – Selecciona al último enemigo
/targetfriend – Selecciona el amigo más cercano
/targetlastfriend – Selecciona al último amigo
/targetlasttarget – Selecciona como objetivo el último objetivo que se tuvo
/targetparty – Selecciona el objetivo del grupo más cercano
/targetraid – Selecciona el objetivo de la banda más cercano

Comandos de Banda
/mt <nombre> – Designa al jugador tanque principal por nombre o por objetivo seleccionado
/mtoff <nombre> – Limpia el tanque principal por nombrado o por objetivo seleccionado
/clearmt – Limpia todos los papeles de tanque principal
/ma <nombre> – Designa el jugador asistente principal
/maoff <nombre> – Limpia el asistente principal por nombre o por objetivo seleccionado
/clearma – Limpia todos los asistentes principales

Montura
/dismount – Desmonta (No hay comando /mount pero se puede usar /use Nombre Montura)

Secuencia de Hechizos
Permite establecer una serie de hechizos para que se lancen uno detrás de otro en cada click de la macro. Cuando finalice la secuencia, volverá al comienzo. El formato es el siguiente:

/castsequence [<opciones>] reset=<#>/target/combat <hechizo1>, <hechizo2>, <hechizo3>

La línea de ‘reset’ puede especificar un número de segundos después de los cuales la secuencia se resetea y por tanto vuelve al principio, o si se debería resetear al cambiar de objetivo o dejar el combate.
La secuencia rastrea el siguiente hechizo en la secuencia hasta que se resetea, y el siguiente hechizo solo avanza si el lanzamiento tiene éxito.
Se puede especificar una condición al comienzo del comando, antes del rest, para filtrar cuando se usará la secuencia.(No se puede establecer una condición para cada hechizo por separado).
Se pueden utilizar tanto objetos como hechizos.
Si el hechizo falla en el lanzamiento (debido al cooldown, fuera de rango, son mana suficiente, etc) entonces la secuencia no pasa al siguiente hechizo. La próxima vez que se pulse en la macro lo intentará lanzar de nuevo. (NOTA: un resistir, esquivar, parar, etc, NO cuenta como hechizo fallido y pasará al siguiente).

Ejemplo de secuencia:

/castsequence Nova de Escarcha, Traslación

La primera vez que se pulsa el botón, se hará Nova, y la siguiente vez que se pulse hará Traslación para alejarse.

/castsequence [combat] Nova de Escarcha, Traslación
/castsequence reset=24 Nova de Escarcha, Traslación

La primera vez pulsada, hace Nova. Si se decide no hacer Traslación, después de 24 segundos, se reseteará a Nova. Dado que el cooldown de la Nova es de 24 segundos, estará listo para usarse de nuevo.

/castsequence Corrupción, Inmolar, Maldición de Agonía

Pulsa el botón 3 veces y lanzará los 3 DoT.

/castsequence reset=combat/target Corrupción, Inmolar, Maldición de Agonía

Cada vez que se cambie de objetivo (como, si por ejemplo el antiguo objetivo ya estuviera medio muerto y vas a por otro), o cada vez que sales de combate (porque la criatura muere antes de que lances todos los DoTs), resetea la secuencia para tí, dejándola lista para comenzar de nuevo.

Opciones
IMPORTANTE: Los nombres de las opciones condicionales deben ir en minúsculas
(Puedes encontrar una guía más detallada de las Opciones en
http://forums.wow-europe.com/thread.html?topicId=184878573&sid=4).

(Nota: el caracter barra vertical es para notar las diferentes posibilidades de un parámetro, pero no debe escribirse)

actionbar:<número> – Evalúa ‘verdadero’ si la la barra de acción actual es la misma que el número indicado.
button:<#> – Evalúa ‘verdadero’ si el botón fue usado para hacer ‘click’ en el hechizo, por defecto 1 (ver abajo).
channeling:<hechizo> – Verdadero si estás canalizando el hechizo indicado. Si no se especifica hechizo, evalúa cualquier hechizo canalizándose.
combat – Verdadero si estás en combate
equipped:<ranuraItem>|<tipoItem>|<subtipoItem> – Verdadero si el objeto está equipado. El objeto puede ser cualquier ranura de inventario, clase de objeto subclase válido.
exists y dead – Verdadero si tu ojetivo está muerto, o existe realmente.
focus
help – Verdadero si el objetivo es amigable.
harm – Verdadero si el objetivo es hostil.
indoors, outdoors – Verdadero si estás en interiores o exteriores respectvamente.
modifier or modifier:shift|ctrl|alt – Verdadero si la tecla indicada se está pulsando cuando el comando se ejecuta.
se pueden distinguir modificadores derechos(r) e izquierdos(l). Ej. rshift/lshift.
mounted, swimming, flying – Verdadero cuando vas montado, nadando o volando respectivamente.
flyable – Verdadero si estás en un terreno apto para montura voladora
pet:<tipo mascota O nombre mascota> – Verdadero si la mascota existe. Acepta tipo (Owl, Bear, Imp) o nombre (Fluffy, MrBigglesworth). Sin modificador (tan solo [pet]) es verdadero si existe cualquier mascota.
stance or stance:# – Verdadero si estás en una postura (stance) o si estás en una en particular (ver abajo)
stealth – Verdadero si estás camuflado.
target=<unidad> – Opción especial. Cambia el objetico del de por defecto de “target” a cualquier id de unidad válido. (ver más abajo)

Opción Equipado
La opción [equipped] funciona de la misma manera, aunque tiene algo de truco. El argumento puede ser una ranuda de inventario (ver abajo), un tipo de objeto, o un subtipo. Ver aquí la lista de tipos y subtipos:http://www.wowwiki.com/ItemType(Importante: los tipos dependen del idioma del juego; como norma general corresponderán con las categorías que aparecen en la casa de subastas).

Lista de ranuras de inventario:

Two-Hand (2 manos)
Bag (bolsa)
Shirt (camisa)
Chest (pechera)
Back (espalda)
Feet (pies)
Finger (dedo)
Hands (manos)
Head (cabeza)
Held In Off-hand (sotenido en la zurda)
Legs (piernas)
Neck (cuello)
Ranged (a distancia)
Off Hand (zurda)
Shoulder (hombros)
Tabard (Tabardo)
Thrown (arrojadiza)
Trinket (alhaja)
Waist (cintura)
One-Hand (una mano)
Main Hand (mano diestra)
Wrist (muñeca)

Algunos ejemplos:

/cast [equipped:Espadas dos manos] Golpe Mortal; Golpe Heroico

…usará Golpe Mortal si estás usando una espada a dos manos.

/cast [equipped:Espadas dos manos/Mazas dos manos/Hachas dos manos/Armas de Asta] Golpe Mortal

…usa el modificador ‘/’ que establece una condición ‘ó’. Ejecutará Golpe Mortal si CUALQUIERA de los tipos está equipado.

/cast [equipped:Escudos] Azote de escudo

…hará un Azote si tienes escudo equipado.

/cast [equipped:Escudos, equipped:Dagas] Embate con escudo

…hará Embate sólo si tienes una daga y un escudo equipados.

/cast [noequipped:Escudos, equipped:Mano Izquierda] Desenfreno

…activará Desenfreno si NO tienes escudo equipado, Y tienes algo equipado en la zurda. En teoría sólo se activaría con un arma en cada mano.

Los comandos /castsequence, /cast, /castrandom, /use, /userandom, /equip, /equipslot aceptan también el número de bolsa y ranura.

Opciones de Botón
La opción [button:<x>] funciona de manera similar al modificador de botón. Normalmente, si haces click izq. en un botón, ejecuta cualquier opción que haya en ese hechizo, o macro en nuestro caso. Sin embargo, si se establece la opción de botón, puedes cambiar el comportamiento para una macro particular.

El botón por defecto es 1, el Izquierdo. Nótese que cuando se activa un botón mediante una tecla asociada es igual que dar al botón Izquierdo. Los botones numerados son: 1 o LeftButton (izquierdo), 2 o RightButton (derecho), 3 o MiddleButton (central), 4 o Button4, 5 o Button5, … o cualquiera de los botones remapeados por el estado seguro de cabeceras (ni idea, pero es lo que pone).

/cast [button:2,target=player] Flash Heal; [help] Flash Heal

…lanza el Flash Heal (curación rápida) en un objetivo amigable, O si haces click con el botón derecho, lanzará Flash Heal sobre tí.

Foco (focus)
Es una nueva característica que te ermitirá guardar un objetivo. Ejemplo:

/focus target

…salvará tu objetivo actual como focus. Esto significa que en cualquier momento puedes usar /target focus para seleccionar la unidad designada con /focus target. Focus soporta las siguientes opciones. Ejemplo:

/cast [target=focus,exists] Polymorph
/castrandom [target=focus,exists] Polymorph, Polymorph: Pig, Polymorph: Turtle

…si quieres un polimorph aleatorio.

Se puede usar el comodín %f para referirse al foco (establecido con /focus) de la misma manera que %t o %n se refiere a tu objetivo. Por ejemplo: /decir Tengo el foco en %f Diría el nombre del personaje que tiene el foco.

Hover Targeting (selección “flotante”)
El Hover Targeting, o la habilidad de lanzar hechizos en diferentes jugadores sin tener que seleccionarlos, tan solo pasando el cursor por encima de un marco de unidad protegido (en este caso party/raid/target/targettarget unitframe). Ejemplo:

/cast [target=mouseover,exist] Toque de sanación; Toque de sanación

…lanzará el Toque de Curación en la persona sobre la que esté el ratón al pulsar la macro sin tener que seleccionarlo. Un ejemplo más avanzado:

/cast [target=mouseover,exist,nomodifier:shift/ctrl/alt] Alivio presto; [target=mouseover,exist,modifier:shift] Toque de sanación; [target=mouseover,exist,modifier:ctrl] Rejuvenecimiento; [target=mouseover,exist,modifier:alt] Recrecimiento; [modifier:ctrl] Forma felina; [modifier:shift] Forma de oso temible; [noswimming] Forma de viaje; [swimming] Forma acuática

…lanzaría Alivio presto/Rejuvenecimiento/Recrecimiento/Toque de sanación si tu ratón está sobre una UnitFrame (el retrato de la party, por ejemplo) dependiendo de que modificador de tecla tengas pulsado (control, alt, …). Sin embargo, si no tienes el ratón sobre un UnitFrame (está en cualquier otro lugar de la pantalla) hará un cambio de forma según las opciones especificadas. En otras palabras, técnicamente es posible poner todas las curaciones estandar y cambios de forma en un solo botón que actúa dependiendo de si el ratón está sobre un UnitFrame y de los modificadores de tecla pulsados.

Modificadores
Los modificadores de clicks por defecto no están configurados para hacer nada, de manera que los addons pueden ampliarlos fácilmente.

Esto antecede a la conversión de marcos de unidad y botones de acción a botones de acción seguros, así que ahora es fácil extenderlos para que soporten los clicks modificados.

/script PlayerFrame:SetAttribute(“*type”, “target”);

… etc.
Shift click tiene por defecto acciones de coger de la barra de acciones, así que si quieres usar la tecla Shift, tendrás que habilitarla explícitamente:

/script ActionButton1:SetAttribute(“shift-type”, “action”); … etc.

Será muy sencillo hacer un addon que haga esto para todos los marcos de unidad y los botones de acción. En 2.0.2, los clicks modificados funcionan de la misma manera que los no modificados, pero quiero que todo el mundo sepa hacerlo por sí mismo si lo quieren hacer más pronto.

Recordad que para las teclas asociadas SHIFT-N y CTRL-N, ya están ligadas por defecto en las opciones.

Opciones de Postura/Forma (Stance)
Funcionan de la misma manera. Si no se pone un número, es verdadero si el jugador está en una Postura cualquiera (los guerreros SIEMPRE están en una Postura). Si se indica un número será verdadero si la Postura está activa. Cada clase tiene unos valores:

Guerrero: Stance:1 -Batalla, Stance:2 -Defensiva, Stance:3, Berseker
Sacerdote: Stance:1 -Forma de Sombra (Shadowform)
Druida: Stance:1 -Oso, Stance:2 -Acuática, Stance:3 -Gato, Stance:4 -Viaje, Stance:5 -Moonkin,Árbol
Rogue: Stance:1 -Camuflado

/cast [stance:1] <Habilidad de postura batalla>; [stance:2] <Habilidad de postura defensiva>; [stance:3] <Habilidad de postura berseker>

…reemplaza <Habilidad de postura *> por lo que quieras.

Las Auras de Paladin ya no son tratadas como Posturas en el sistema de opciones de Macros. Ten en cuenta que si mantienes una Postura (como un warrior que nunca hace el quest de la Postura Defensiva) tus números de Postura disminuyen, (ej. Postura Berserker sería el 2). Algunos ejemplos.

/cast [nostance] Bear Form

Si no estás en una forma, cambia a forma de oso.

/cast [stance:1] Overpower; [stance:2] Sunder Armor; [stance:3] Whirlwind

Si estás en Postura de Batalla usa Overpower, en Defensivo Sunder Armor, y Whirlwind en la Berseker.

/cast [stance:1] Growl; [stance:3] Claw

Usa Growl en forma de Oso o Claw en forma de Gato.

/cast [nostance:3] Cat Form

Te pone en forma de Gato si no lo estás. Si lo estás, esto NO te quitará la forma (puesto que no cumple la condición).

Opciones de Objetivo (Target Options)
La opción [target=unit] es una opción especial. En lugar de evaluar ‘verdadero’ o ‘falso’, cambia el objetivo del hechizo que venga a continuación y el objetivo de las otras opciones. “Unit” será un tipo de unidad válido, ej. “player”, “target”, “targettarget”, “party1″, “party1target”, etc etc. http://www.wowwiki.com/UnitId

Te en cuenta que cada hechizo tiene un objetivo de “objetivo” (target of target) por defecto. Por ejemplo:

/cast [help] Sanación superior

es lo mismo que:

/cast [target=target, help] Sanación superior

Hasta que no añadas una opción [target=unit], el objetivo por defecto será tu objetivo actual.
Posibles ejemplos de [target=unit]:

/cast [target=player] Sanación relámpago

Este hechizo siempre hace Sanación relámpago sobre tí. Nótese que el objetivo actual NO cambia.

/cast [help] Sanación relámpago; [target=targettarget] Sanación relámpago

Este lanza Sanación relámpago en tu objetivo si es amigable, O lanzará el Sanación relámpago en el objetivo de tu objetivo.

/cast [help, combat] Sanación relámpago; [help, nocombat] Sanación superior; [target=targettarget, help, combat] Sanación relámpago; [target=player] Sanación superior

Esta hará una de 1) Lanzar Sanación relámpago si el objetivo es amigable y estás en combate, 2) lanza Sanación superior si el objetivo es amigo y no estás en combate, 3) lanza Sanación relámpago en el objetivo de tu objetivo si estás en combate y esa unidad es amistosa, o si ninguna de estas situaciones es cierta, lanza Sanación superior sobre tí mismo.

Si se usa el UnitId “none” actua como si NO tuvieras objetivo. Ejemplo:

/cast [target=none] Disipar Magia

Esto lanza Disipar y luego pregunta por un objetivo, independientemente de quién tengas seleccionado en ese momento.

Macros de Ejemplo

Macros Generales
Mount

/use [nomounted,outdoors] Brida de corcel de guerra negro

Esto intentará montar si estás en exteriores y no montado.
Usar venda
Esta macro intentará siempre ponerte una venda independientemente de tu objetivo seleccionado.

/use [target=player] Venda gruesa de paño

1. Si pulsas la macro mientras aprietas la tecla ALT, te vendará a tí mismo.
2. Si pulsas la macro mientras aprietas la tecla CTRL, vendará a tu mascota.
3. Si pulsas la macro sin más, vendarás a un objetivo amigable.

/use [modifier:alt,target=player] Venda gruesa de paño
/use [modifier:ctrl,target=pet] Venda gruesa de paño
/use [help] Venda gruesa de paño

Esta macro usará una venda en tu objetivo si es posible, o a tí mismo en caso contrario. Mientras no se pulse ALT, en cuyo caso siempre será sobre tí mismo.

/use [help,modifier:noalt] Venda gruesa de paño; [target=player] Venda gruesa de paño

Guía Avanzada